[Paimpol]Effaroucheur de moineaux

A Paimpol, un couple de pigeon, nous chie sur le parking régulièrement. Ils sont perchés sur le cèdre du Liban soit coté cabanon jardin, soit coté Barbecue. Annie passe à chaque fois une heure pour tout nettoyer.

Comment faire fuir ces 2 pigeons ?

En consultant internet on voit qu'il existe des effaroucheurs à base de laser verts (a priori cette couleur verte est importante ?) pour une soixantaine d'euros. Le problème est que le laser semble faire seulement un mouvement horizontal. Je souhaiterais un mouvement de haut en bas et de gauche à droite. 

Du coup j'ai acheté un tilt sur 2 servos (9€) et un crayon laser (9euros). Avec une carte ESP8266 et le soft ESPEasy j'espère pouvoir faire le mouvement de balayage du laser.

Pour le pilotage des Servos soit une carte Arduino, soit ESP et des bibliothèques gerant les Servos moteurs, et se faire un sketch dans l'IDE Arduinos. En utilisant ESPEasy j'espère pouvoir modifier facilement le programme à distance à partir du moment où la carte ESP sera connectée en wifi.

Avec ESPEasy il existe les règles où l'on peut faire un peu de programmation. Après plusieurs essais et l'aide de ChatGPT, j'ai pu faire le programme suivant :

Il faut activer dans la partie Tools/Advance les règles et cela ajoute un onglet Rules où l'on accède à une fenêtre où mettre sont code. La doc sur ESPEasy est pas trop mal faite et avec les exemples dans les forums on arrive à s'en sortir (mais j'ai mis 2 après midi à réussir à jouer avec les varaible pour piloter les valeurs envoyées aux servos.

// ==============================
// Initialisation au boot
// ==============================
on System#Boot do
  Let,0,90      // Servo 1 position initiale (centre)
  Let,1,90      // Servo 2 position initiale (centre)
  servo,1,12,[VAR#0]
  servo,2,13,[VAR#1]
  Let,2,5       // direction 1 = monter, -1 = descendre
  Let,3,5       // direction 1=droit, -1=gauche
  timerSet,1,10 // démarrage timer 10sec
endon

// ==============================
// Timer pour mouvement fluide
// ==============================
on Rules#Timer=1 do
  // Calcul nouvelle position pour Servo 1
  Let,0,[VAR#0]+[VAR#2]
   //LogEntry, [VAR#0]
  // Calcul nouvelle position pour Servo 2 (même mouvement)
  //Let,1,[VAR#1]+[VAR#3]
   //LogEntry,[VAR#1]

  // Vérifie limites -45° à +45° (45 à 135 en valeur servo)
  if [VAR#0]>135
    Let,0,135
    //Let,1,180
    Let,2,-5  // inverser direction
  endif

  if [VAR#0]<45
    Let,0,45
    //Let,1,0
    Let,2,5   // inverser direction servo 0
    Let,1,[VAR#1]+[VAR#3]  //on ne bouge le servo1 droite gauche que lorsque le servo 0 a fait un balayage.
  endif

  if [VAR#1]>180
     Let,1,180
     Let,3,-5    //inverser direction droite gauche servo 1
  endif

  if [VAR#1]<0
     Let,1,0
     Let,3,5     //inverser direction gauche droite
  endif

  // Mettre à jour les servos
  servo,1,12,[VAR#0]
  servo,2,13,[VAR#1]

  // Relancer le timer
  timerSet_ms,1,20     //timer de 20ms pour relancer le déplacement du servo

endon

Il faut faire très attention à la syntaxe ; ne pas mettre d'espace sinon la gestion des variables ne se fait pas. La commande Let était mal retranscrite dans ChatGPT...

Pour avoir la commande Servo j'ai du prendre une version Collection A de ESPEasy car la version Normal ne semble pas l'avoir. Je n'ai pas trouvé de Device Servo dans cette version Collection A, mais la commande Servo,1,12,90 est bien prise en compte, et le programme ci dessus fonctionne correctement avec les servos mis en GPIO12 et GPIO13 soit pattes D6 et D7 de la carte NodeMCDU V3 achetée sur Aliexpress.

La carte sera alimentée en 5v pour alimenter également les 2 servos. J'espère que le signal en 3,3 sera de niveau suffisant pour piloter les 2 servos.

Sinon j'utiliserais une carte Arduino UnO qui fonctionne en 5v et les sorties aussi.